Criando consulta customizada desde o back-end via API até o front-end com Angular e POUI

Vamos criar uma tela de consulta totalmente customizada que possamos usar no ERP Datasul da TOTVs. Vamos criar uma consulta de cidades neste guia.

Primeiramente vamos criar a API que fará a coleta dos dados no sistema usando os recursos apresentados n

este link: https://tdn.totvs.com/display/public/FRAMJOI/Desenvolvimento+de+APIs+para+o+produto+Datasul

Também vamos usar o programa criado pelo Rubinhos e disponibilizado no GIT da TOTVs neste endereço: https://github.com/totvs/CoffeeAndCodeJOI/blob/master/dts-thf/back-end/fnd/api/v1/idiomas.p

Em seguida vamos criar uma tela de consulta com Angular e POUI e tentar inserir no ERP Datasul baseados no guia deste endereço: https://po-ui.io/guides/getting-started

Criando a API para consulta

Vamos criar uma procedure chamada api_cidade.p, segue o código:

USING Progress.Json.ObjectModel.*.
USING Progress.Json.ObjectModel.ObjectModelParser.
USING Progress.Json.ObjectModel.JsonArray.
USING Progress.Json.ObjectModel.JsonObject.

{utp/ut-api.i}
{utp/ut-api-utils.i}
{utp/ut-api-action.i piGet GET /cidade/~*}
{utp/ut-api-action.i piGetAll GET /~*}
{utp/ut-api-notfound.i}

define temp-table ttCidade no-undo
    field cidade like mgcad.cidade.cidade
    field sigla  like mgcad.cidade.sigla
    field estado like mgcad.cidade.estado
    field pais   like mgcad.cidade.pais
    field cdn-munpio-ibge like mgcad.cidade.cdn-munpio-ibge serialize-name "cdnMunpioIbge".

/*------------------------------------------------------------------------------
 Retorna a lista de cidades.
------------------------------------------------------------------------------*/
PROCEDURE piGetAll:
    DEFINE INPUT  PARAMETER jsonInput  AS JsonObject NO-UNDO.
    DEFINE OUTPUT PARAMETER jsonOutput AS JsonObject NO-UNDO.
    
    DEFINE VARIABLE jsonRetorno AS JsonArray NO-UNDO.
    
    EMPTY TEMP-TABLE ttCidade.
    EMPTY TEMP-TABLE RowErrors.
    
    for each mgcad.cidade no-lock
        by cidade:
        create ttCidade.
        buffer-copy mgcad.cidade to ttCidade.
    end.
    
    ASSIGN jsonRetorno = NEW JsonArray().
    jsonRetorno:Read(TEMP-TABLE ttCidade:HANDLE).
    
    RUN createJsonResponse(
        INPUT jsonRetorno, 
        INPUT TABLE RowErrors, 
        INPUT FALSE, 
        OUTPUT jsonOutput).
END PROCEDURE.
/*------------------------------------------------------------------------------
 Retorna os dados da cidade informada por parametro (Parametro de URL)
------------------------------------------------------------------------------*/
PROCEDURE piGet:
    DEFINE INPUT  PARAMETER jsonInput  AS JsonObject NO-UNDO.
    DEFINE OUTPUT PARAMETER jsonOutput AS JsonObject NO-UNDO.
    DEFINE VARIABLE jsonRetorno AS JsonArray NO-UNDO.
    define variable oRequestParser as JsonAPIRequestParser no-undo.
    define variable oQueryParams as JsonObject no-undo.

    DEFINE VARIABLE vAux AS CHARACTER NO-UNDO.

    EMPTY TEMP-TABLE ttCidade.
    EMPTY TEMP-TABLE RowErrors.

    ASSIGN
        oQueryParams = NEW JsonObject()
        jsonRetorno = NEW JsonArray().

    oRequestParser = NEW JsonAPIRequestParser(jsonInput).
    assign oQueryParams = oRequestParser:getQueryParams().
 

    /* se vazio o GetJsonText() retorna 2 */
    if length(oQueryParams:GetJsonText()) <= 2 then do:
        CREATE RowErrors.
        ASSIGN
            RowErrors.ErrorNumber      = 42424
            RowErrors.ErrorType        = "error"
            RowErrors.ErrorDescription = "Nenhum parâmetro de busca informado"
            RowErrors.ErrorSubType     = "ERROR".        
    end.
    else do:
        if oQueryParams:has("cidade") then do:
            /* getQueryParams retorna JsonArray, vamos estrair a informação na primeira posição */
            assign jsonRetorno = oQueryParams:GetJsonArray("cidade").
            assign vAux = string(jsonRetorno:GetJsonText(1)).

            for each mgcad.cidade no-lock
                where mgcad.cidade.cidade = vAux
                by cidade:
                create ttCidade.
                buffer-copy mgcad.cidade to ttCidade.
            end.

            /* Se for filtrar estado */
            /* :has é case sensitive */
            if oQueryParams:has("estado") then do:
                assign jsonRetorno = oQueryParams:GetJsonArray("estado").
                assign vAux = string(jsonRetorno:GetJsonText(1)).
                for each ttCidade
                    where ttCidade.estado <> vAux
                    :
                    delete ttCidade.
                end.
            end.
            /* Se for filtrar estado */
            if oQueryParams:has("pais") then do:
                assign jsonRetorno = oQueryParams:GetJsonArray("pais").
                assign vAux = string(jsonRetorno:GetJsonText(1)).
                for each ttCidade
                    where ttCidade.pais <> vAux
                    :
                    delete ttCidade.
                end.
            end.
        end.
    end.

    if not can-find(first ttCidade) then do:
        CREATE RowErrors.
        ASSIGN
            RowErrors.ErrorNumber      = 42424
            RowErrors.ErrorType        = "error"
            RowErrors.ErrorDescription = "Nenhum registro localizado"
            RowErrors.ErrorSubType     = "ERROR".
    end.
    else
        jsonRetorno:Read(TEMP-TABLE ttCidade:HANDLE).

    if not can-find(first RowErrors) then do:
        RUN createJsonResponse(
            INPUT jsonRetorno, 
            INPUT TABLE RowErrors, 
            INPUT FALSE, 
            OUTPUT jsonOutput).
    end.
    else do:
        RUN createJsonResponse(NEW JsonObject(), INPUT TABLE RowErrors, INPUT FALSE, OUTPUT jsonOutput).
    end.
END PROCEDURE.

Resultado da consulta realizado pelo Postman:

O próximo passo é criar a tela de consulta de dados .

Porem antes vem um detalhe importante. Ao tentar fazer uma consulta pode estar tendo um retorno de falha de login.

Acontece pois a API vai tentar logar o usuário antes da consulta, para conseguir acessar deve ser informado um usuário e senha cadastrados no sistema Datasul, e a senha deve estar convertida para SHA1

DEFINE VARIABLE testPass AS CHARACTER NO-UNDO.
testPass = BASE64-ENCODE(SHA1-DIGEST(LC("testPassword"))).

O resultado desta conversão será “i7YRj4/Wk1rQh2o740pxfTJwj/0=”

Para realizar o teste no Postman por exemplo devemos configurar Basic Auth em Autorization: